Populating Tree by Procedure

PROCEDURE p_populatetree (p_htree VARCHAR2, p_clause VARCHAR2)
IS
   htree        item;
   rg_prop_id   recordgroup;
   rg_prop      VARCHAR2 (100);
   v_ignore     NUMBER;
   node         ftree.node;
   state        VARCHAR2 (100);
   area_type    NUMBER;
BEGIN
   htree := FIND_ITEM (p_htree);
   rg_prop_id := FIND_GROUP ('rg_prop');

   IF NOT ID_NULL (rg_prop_id)
   THEN
      DELETE_GROUP (rg_prop_id);
   END IF;

   rg_prop_id := CREATE_GROUP_FROM_QUERY ('rg_prop', p_clause);
   v_ignore := POPULATE_GROUP (rg_prop_id);
   ftree.SET_TREE_PROPERTY (htree, ftree.record_group, rg_prop_id);
   node := ftree.FIND_TREE_NODE (htree, '');

   WHILE NOT ftree.ID_NULL (node)
   LOOP
      state := ftree.GET_TREE_NODE_PROPERTY (htree, node, ftree.node_state);

      IF state = ftree.expanded_node
      THEN
         ftree.SET_TREE_NODE_PROPERTY (htree,
                                       node,
                                       ftree.node_state,
                                       ftree.collapsed_node
                                      );
      END IF;

      node :=
         ftree.FIND_TREE_NODE (htree,
                               '',
                               ftree.find_next,
                               ftree.node_label,
                               '',
                               node
                              );
   END LOOP;
END;